View Source Code

SourceFileName = "samples/mail_list.asp"

C:\inetpub\wwwroot\aspsample\samples\mail_list.asp

<%
Select Case Request.QueryString("ACT")
  Case "WRITE"
    Response.Cookies("userid-webmail")("server") = Request.Form("server") 
    Response.Cookies("userid-webmail")("user") = Request.Form("user") 
    Response.Cookies("userid-webmail")("pass") = Request.Form("pass") 
    Response.Cookies("userid-webmail").Expires = Date + 30
End Select
%>
<!-- 下記のuseridの部分をお客様のユーザーIDと置き換えて下さい。-->
<!-- 実行には、この「mail_list.asp」の他に「mail_login.asp」と「mail_body.asp」も必要となります。 -->
<HTML>
<HEAD>
<TITLE>Web Mail</TITLE>
</HEAD>
<BODY>
<%
Set oBasp21 = Server.CreateObject("Basp21")

sServer = Request("SERVER")
sUser = Request("USER")
sPass = Request("PASS")
sDir = "c:\InetPub\wwwroot\userid\_exc\temp"

If sServer = "" or sUser = "" or sPass = "" Then
  Response.Write "未入力の項目があります。"
  Response.Write "</BODY></HTML>"
  Response.End
End If

' この下の一行は絶対に変更しないで下さい。
If sServer <> "po.cnet.ne.jp" And sServer <> "po.post.gr.jp" Then
  Response.Write "残念ながらpo.cnet.ne.jpとpo.post.gr.jp以外はメール受信できません。"
  Response.Write "</BODY></HTML>"
  Response.End
End If

sOut = oBasp21.RcvMail(sServer, sUser, sPass, "STAT", sDir)
If IsArray(sOut) Then
  sBuf = Split(sOut(0), " ")
  If sBuf(0) > 0 then
    Response.Write sBuf(0) & " 件のメールが届いています。<BR>" & vbNewLine
    Response.Write "<HR>" & vbNewLine
  Else
    Response.Write "新しいメールは届いていません。<BR>" & vbNewLine
    Response.Write "</BODY></HTML>"
    Response.End
  End If
Else
  Response.Write "ERROR! " & sOut
  Response.Write "</BODY></HTML>"
  Response.End
End If

Response.Write "<TABLE BORDER=1 CELLSPACING=0 CELLPADDING=4>" & vbNewLine
Response.Write "<TR><TD WIDTH=300>件名</TD><TD>差出人</TD><TD>日付</TD></TR>" & vbNewLine
sOut = oBasp21.RcvMail(sServer, sUser, sPass, "LIST", sDir)
If IsArray(sOut) Then
  iNo = 0
  For Each sHeader In sOut
    iNo = iNo + 1
    sBuf = sPlit(sHeader, Chr(9))
    BUF = "<TR>"
    BUF = BUF & "<TD>" & "<A HREF=""mail_body.asp?NO=" & iNo & """>" & Mid(sBuf(0),9) & "</A></TD>"
    BUF = BUF & "<TD>" & Mid(sBuf(1),6) & "</TD>"
    BUF = BUF & "<TD>" & Mid(sBuf(2),6) & "</TD>"
    BUF = BUF & "</TR>"
    Response.Write BUF & vbNewLine
  Next
Else
  Response.Write "メールはありません。"
End If
Response.Write "</TABLE>" & vbNewLine

%>

</BODY>
</HTML>